Attribute VB_Name = "Module1"
Private Function SolunEdKpl(ByVal Osoite As String) As Long
'Molempien funktioiden (SolunEdKpl ja SolunSeKpl)aloittava rivi
'  (On Error GoTo Virhe) kääntää virheenhalilintatilan päälle,
'  joten koodi ei joudu suorituksenaikaiseen virheeseen rivillä 2,
'  vaan virheenhallinta siirtää näissä tilanteissa kontrollin funktion
'  lopussa olevaan Virhe-leimaan.
'Täällä asetetaan funktion vastaus nollaksi.
  On Error GoTo Virhe
  SolunEdKpl = Range(Osoite).DirectPrecedents.Count
  Exit Function
Virhe:
  SolunEdKpl = 0
End Function

Private Function SolunSeKpl(ByVal Osoite As String) As Long
  On Error GoTo Virhe
  SolunSeKpl = Range(Osoite).DirectDependents.Cells.Count
  Exit Function
Virhe:
  SolunSeKpl = 0
End Function

Sub TestaaSolunEdKplJaSolunSeKpl()
  MsgBox SolunEdKpl("A1") & " - " & SolunSeKpl("A1")
End Sub

Sub SolunValittomatEdeltajat(ByVal Osoite As String)
  MsgBox Range(Osoite).DirectPrecedents.Count
  MsgBox Range(Osoite).DirectPrecedents.Address
  Range(Osoite).DirectPrecedents.Select
End Sub

Sub TestaaSolunValittomatEdeltajat()
  If SolunEdKpl("F17") > 0 Then SolunValittomatEdeltajat ("F17")
End Sub

Sub SolunKaikkiEdeltajat(ByVal Osoite As String)
  MsgBox Range(Osoite).Precedents.Count
  MsgBox Range(Osoite).Precedents.Address
  Range(Osoite).Precedents.Select
End Sub

Sub TestaaSolunKaikkiEdeltajat()
  If SolunEdKpl("F17") > 0 Then SolunKaikkiEdeltajat ("F17")
End Sub

Sub SolunValittomatSeuraajat(ByVal Osoite As String)
  MsgBox Range(Osoite).DirectDependents.Count
  MsgBox Range(Osoite).DirectDependents.Address
  Range(Osoite).DirectDependents.Select
End Sub

Sub TestaaSolunValittomatSeuraajat()
  If SolunSeKpl("E1") > 0 Then SolunValittomatSeuraajat ("E1")
End Sub

Sub SolunKaikkiSeuraajat(ByVal Osoite As String)
  MsgBox Range(Osoite).Dependents.Count
  MsgBox Range(Osoite).Dependents.Address
  Range(Osoite).Dependents.Select
End Sub

Sub TestaaSolunKaikkiSeuraajat()
  If SolunSeKpl("E1") > 0 Then SolunKaikkiSeuraajat ("E1")
End Sub

Sub SolunEdeltajatJaSeuraajat(ByVal Osoite As String)
  Range(Osoite).ShowPrecedents
  Range(Osoite).ShowDependents
End Sub

Sub TestaaSolunEdeltajatJaSeuraajat()
  If SolunEdKpl("F8") > 0 Then SolunEdeltajatJaSeuraajat "F8"
End Sub

Sub PoistaKaikkiNuolet()
  ActiveSheet.ClearArrows
End Sub
  
Sub PoistaSolunNuolet(ByVal Osoite As String)
  Range(Osoite).ShowPrecedents Remove:=True
  Range(Osoite).ShowDependents Remove:=True
End Sub

Sub TestaaPoistaSolunNuolet()
  PoistaSolunNuolet "F8"
End Sub